# 1 "/Bruker/35/exp/stan/nmr/lists/pp/ko_NOEHSQCN_Cdec3d.5"
;3D 15N-separated NOESY-HSQC with Water-flip backed HSQC experiment.
;ko_noehsqc3d			980218
;	modified for F3:15N version by koshiba	010503
;	modified for 13C decoupling version by koshiba	010910
;	modified for 13C decoupling using shaped pulses by koshiba	011229
;	modified for 13C decoupling using shaped pulses by koshiba	020208
;
;F1:1H      [p1,pl1@-1db ~10u
;           [p5,pl5@40db ~1.0m for WFB
;F3:15N     [p21,pl3@     ~40u]
;           [pcpd3,pl13@ ~250u,WALTZ16 for decoupling]
;
;Gradient pulses (total: 6). "Sine100" or "Sine50" is used.
;  p14:5.0m,gp0(spoil) +30 ; OPT
;  p15:2.0m,gp1(spoil) +28
;  p16:3.0m,gp2(spoil) +30
;  p17:2.5m,gp3(spoil) -25
;  p18:1.0m,gp4(spoil) +30
;  p19:400u,gp5(echo)  -15
;  p19:400u,gp5(echo)  -15
;
;Loop counter
;l2:1H
;l3:15N
;

"l2=td1/2"
"l3=td2/2"

# 1 "/Bruker/35/exp/stan/nmr/lists/pp/Avance.incl" 1
;Avance2.incl
;   for 1
;
;avance-version (03/02/17)





















































































































;$Id: Avance2.incl,v 1.7.2.3 2003/02/25 14:48:48 ber Exp $
# 30 "/Bruker/35/exp/stan/nmr/lists/pp/ko_NOEHSQCN_Cdec3d.5" 2

# 1 "/Bruker/35/exp/stan/nmr/lists/pp/Grad.incl" 1
;Grad2.incl  -  include file for Gradient Spectroscopy
;   for 1
;
;avance-version (02/05/31)



















define list<gradient> EA=<EA>



;$Id: Grad2.incl,v 1.7 2002/06/12 09:04:22 ber Exp $
# 31 "/Bruker/35/exp/stan/nmr/lists/pp/ko_NOEHSQCN_Cdec3d.5" 2


;for Gradients
;"p14=5.0m"
;"p15=2.0m"
;"p16=3.0m"
;"p17=2.5m"
;"p18=1.0m"
;"p19=400u"

;defined parameters.
"d2=2.25m"
"d5=p21-p1"

"d15=p23/2.0-p21"
"d16=p23/2.0-p1"
"d17=p24/2.0-p21"

"d24=d2-p19-p5-125u"
"d25=d2-p19-p5-p21*2.0-155u"
;"d25=d2-p19-p5-105u"
"d23=p24/2.0-p1"

;for t1 evolution
"d0=in0*0.5-p1*2.0/3.14" 	;phase correction 90(+45),-180
;"d0=4u"
;for t2(15N) evolution
"d10=in10*0.5-p21*2.0/3.14"     ; 90/-180 phase collection.
;"d10=4u"

;mixing time(d19=80ms)
"d18=d19-p21-p13-p15-p16-2239u" ; mixinig delay

;pulse sequence.

  30m setnmr3^0 setnmr0^34^32^33
1 ze
2 75m do:f3
3 15m
  15m
4 15m
  15m
5 15m
  15m
6 20u
  20u pl1:f1
  20u pl15:f2
  20u pl3:f3
  d1  ; d1 = relax. delay - 150ms
;  (p21 ph10):f3                            ;OPTIONAL
;==========                               ;OPTIONAL
;        20u setnmr3|0 setnmr0|34|32|33   ;
;        5u              ;                 ;OPTIONAL
;        p14:gp0         ; PFG (homospoil) ;OPTIONAL
;        100u                              ;OPTIONAL
;==========                               ;OPTIONAL
;  500u                                    ;OPTIONAL
;********** t1(1H) evolution.
  (d16 p1 ph1 d0 d0 p1 ph0 d16):f1 (d0 p23:sp2 ph20):f2 (d0 d15 p21*2.0 ph13):f3
;********** Mixing period.
  5u
  d18			; mixing time.
  20u setnmr3|0 setnmr0|34|32|33
;==========
        5u              ;
        p15:gp1         ; PFG (homospoil)
        100u pl2:f2
;==========
  1m
  (p21 ph10):f3
  4u
  (p13 ph20):f2
;==========
        5u              ;
        p16:gp2         ; PFG (homospoil)
        100u pl17:f2
;==========
  1m
;********** INEPT 1H -> 15N.
  (p1 ph0):f1
  d2 
  (d5 p1*2.0 ph2):f1 (p21*2.0 ph10):f3
  d2
  (p1 ph4):f1
  5u
  20u pl5:f1
  (p5 ph5:r):f1	 	; water-flip back
;==========
        5u              ;
        p17:gp3         ; PFG (homospoil)
        50u             ;
;========== t2 (15N) evolution.
  1m pl1:f1
  (d17 p21 ph11 d10 d10 p21 ph10 d17):f3 (d10 p24:sp1 ph20):f2 (d10 d23 p1*2.0 ph0):f1 
;==========
        5u              ;
        p18:gp4         ; PFG (homospoil)
        50u             ;
;==========
  1m pl5:f1
  (p5 ph7:r):f1		; water-flip back
  5u
  20u pl1:f1
  (p1 ph0):f1
;==========
        5u              ;
        p19:gp5         ; PFG (echo)
        95u             ;
;==========
  d24 pl5:f1
  (p5 ph8:r):f1		; water-flip back
  5u
  20u pl1:f1			; 1H power -> hl1
  (d5 p1*2.0 ph3):f1 (p21*2.0 ph10):f3
  5u
  20u pl5:f1			; 1H power -> hl3
  (p5 ph8:r):f1		; water-flip back
;==========
        5u              ;
        p19:gp5         ; PFG (echo)
        95u             ;
;==========
  d25 setnmr3^0 setnmr0^34^32^33
  (p21 ph10 5u p21 ph14):f3 
  5u
  20u pl13:f3
;---------- Acquisition.
  go=2 ph31 cpd3:f3
  60m do:f3 wr #0 if #0 zd
  15m ip1*2
  lo to 3 times 2
  15m id0
  15m ip31*2
  lo to 4 times l2
  15m rd0
  15m ip11
  lo to 5 times 2
  15m id10
  15m ip31*2
  lo to 6 times l3
  30m setnmr3^0 setnmr0^34^32^33
exit 

;phases for 1H pulses.
ph0=0
ph1=(8)7 3
ph2=1
ph3=2 
ph4=1 1 1 1  3 3 3 3
ph5=(360) 0				;x
ph7=(360) 180				;-x
ph8=(360) 0 				;x
;phases for 15N pulses.
ph10=0
ph11=0 0 2 2
ph13=3 1
ph14=0 0 0 0  2 2 2 2
;phases for 13C pulses.
ph20=0
ph21=1
;--- Reciever Phase ---
ph31=0 2 2 0  2 0 0 2



;for 1H
;p1:1H 90deg hard pulse ~10u
;pl1:1H hard pulse 
;
;p5:water flip back pulse ~1ms (phcor5,7,8)
;pl5:water flip back pulse 
;
;d19:mixing time
;
;for 15N
;p21:15N 90deg hard pulse (~45us)
;pl3:15N hard pulse
;pl13:15N CPD pulse (pcpd3)
;pcpd3:15N CPD pulse (~250us) 
;
;for 13C
;p13:13C 90deg hard pulse (~15us)
;pl2:13C hard pulse
;p23:13C 180deg shape pulse (0-140ppm)
;sp2:13C 180deg shape pulse (p23;ko_CRP80-)
;pl15:13C 180deg shape pulse (p23) (=sp2)
;p24:13C 180deg shape pulse (40-180ppm)
;sp1:13C 180deg shape pulse (p24;ko_CRP80-) 
;pl17:13C 180deg shape pulse (p24) (=sp1)